aboutsummaryrefslogtreecommitdiff
path: root/personal_infra/puppet/modules/root_mail/manifests/init.pp
blob: 66cfeb877a2484a69b818d14d4508210e68283e0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
class root_mail {
  package {'postfix':}
  ->
  service {'postfix':
    ensure => running,
    enable => true,
  }

  $cron_service = case $facts['os']['family'] {
    'Debian': { 'cron' }
    'RedHat': { 'crond' }
    default: { fail($facts['os']['family']) }
  }

  # if crond doesn't see /usr/bin/sendmail on startup, it won't send mails
  Package['postfix']
  ~>
  service{$cron_service:
    ensure => running,
  }

  if($facts['os']['family'] == 'RedHat') {
    if($facts['os']['release']['major'] == '9') {
      package {'s-nail':}
    }
    else {
      package {'mailx':}
    }
  }

  mailalias {'root':
    recipient => lookup('mail.root_mail'),
    require => Package['postfix'],
  }
  ~>
  exec {'/usr/sbin/postalias /etc/aliases':
    creates => '/etc/aliases.db',
  }
  ~>
  Service['postfix']
}